#!/usr/bin/env perl
# -*- perl -*-
#
# USAGE: analyze_mail [ <option> ]? <host> <username> <password> [<inbox>]*
#
# where options include
#
#  -l   list inboxes
#  -h   print help
# 
# and the last arguments are the names of the inboxes to search.  If
# none are supplied, we use INBOX.
#
# Output is the lines such as the following
#
#  <date> \t <email>
#
# This uses Net::IMAP::Simple and Email::Simple found here:
#  - http://search.cpan.org/~cfaber/Net-IMAP-Simple-1.17/
#  - http://search.cpan.org/dist/Email-Simple/
# ------------------------------------------------------------------

use strict;
use warnings;
use Net::IMAP::Simple;
use Email::Simple;
use Getopt::Std;

# --------------------------------------------------
# Subroutines
# --------------------------------------------------

sub note {
    print STDERR "@_"
}

sub noteln {
    print STDERR "@_\n"
}

sub main {

    my %options = %{ shift @_ };
    
    my $host = shift @_;
    my $user = shift @_;
    my $pass = shift @_;
    
    my @inboxes = ();
    if ($#_ == -1) {
        push @inboxes, ('INBOX');
    } else {
        @inboxes = @ARGV;
    }
    
    my $server = Net::IMAP::Simple->new($host);
    $server->login($user,$pass);
    
    # List inboxes
    if (defined $options{l}) {
        foreach my $folder ($server->mailboxes) {
            my $num_messages = $server->select($folder);
            next if !$num_messages;
            note $folder;
            note("." x (30-length($folder)));
            noteln $num_messages;
        }
    }
    
    # Search all the inboxes
    foreach my $folder (@inboxes) {
        noteln "Reading $folder";
        my $num_messages = $server->select($folder);
        my $num_processed = 0;
        foreach my $msg ( 1 .. $num_messages ) {

            my $email = Email::Simple->new( join '', @{$server->get($msg)} );

            # Print dates and from addresses
            my $date = $email->header('Date');
            my $from = $email->header('From');
            if ($date && $from) {
                $num_processed += 1;
                if ($num_processed%100 == 0) {
                    noteln "$folder: $num_processed / $num_messages"
                }
                print "$date\t$from\n";
            }
        }
    }
    
    $server->quit;

}


# --------------------------------------------------
# Main
# --------------------------------------------------

my %options = ();
getopts("lhd",\%options);

# Print help?
if (defined $options{h}) {
    print STDERR "Usage analyze_mail [ -l ]? <host> <username> <password> [<inbox>]*\n";
    print STDERR "\n";
    print STDERR "where options include\n";
    print STDERR "\n";
    print STDERR "  -l   list inboxes\n";
    print STDERR "  -d   print dates\n";
    print STDERR "  -h   print help\n";
    print STDERR "\n";
    exit 0;
}

if ($#ARGV < 2) {
    print STDERR "Usage: $0 <host> <username> <password>\n";
    exit 1;
}

main \%options, @ARGV;